Appendix A: Mplus Program for Fitting Bayesian One Factor ACE model.

TITLE:Program code example of Bayesian Estimation of Traditional One Factor ACE Genetic Model. Example considered consists of five manifest variables.

DATA: FILE = twinlist.dat; !file containing names of Monte Carlo Replications;

TYPE = MONTECARLO;!Request Monte Carlo Analysis;

!DATA: file = twin1.dat; !Comment out above two lines and uncomment this line if single data set analysis is desired.

VARIABLE: NAMES = twin1y1-twin1y5 twin2y1-twin2y5 group; !Read in Variable Names;

USEVARIABLES twin1y1-twin1y5 twin2y1-twin2y5 ;! Specify Variable Names;

CLASSES = zygosity (2);

KNOWNCLASS = zygosity (group=1 group=2);

ANALYSIS: model=nocovariances; !Default to Orthogonal Factor structure;

TYPE = MIXTURE; ESTIMATOR=BAYES; BITERATION=5000; THIN=15; CHAIN=1;

MODEL:

%OVERALL% !Begin MZ twin program specification;

!Additive Genetic Factor Specified as Single Factor (i.e., Correlation=1 across Twin Pairs);

a1 by

Twin1Y1\*0.4 (Addit1)

Twin1Y2\*0.4 (Addit2)

Twin1Y3\*0.4 (Addit3)

Twin1Y4\*0.4 (Addit4)

Twin1Y5\*0.4 (Addit5)

Twin2Y1\*0.4 (Addit1)

Twin2Y2\*0.4 (Addit2)

Twin2Y3\*0.4 (Addit3)

Twin2Y4\*0.4 (Addit4)

Twin2Y5\*0.4 (Addit5);

!Common Environmental Factor;

c by

Twin1Y1\*.57 (Comm1)

Twin1Y2\*.57 (Comm2)

Twin1Y3\*.5 (Comm3)

Twin1Y4\*.5 (Comm4)

Twin1Y5\*.45 (Comm5)

Twin2Y1\*.57(Comm1)

Twin2Y2\*.57 (Comm2)

Twin2Y3\*.5 (Comm3)

Twin2Y4\*.5(Comm4)

Twin2Y5\*.45(Comm5);

!Unique Environment Factor for Twin 1;

e1 by

Twin1Y1\*.42 (ENV1)

Twin1Y2\*.42 (ENV2)

Twin1Y3\*.42 (ENV3)

Twin1Y4\*.42 (ENV4)

Twin1Y5\*.58 (ENV5);

!Unique Environment Factor for Twin 2;

e2 by

Twin2Y1\*.42 (ENV1)

Twin2Y2\*.42 (ENV2)

Twin2Y3\*.42(ENV3)

Twin2Y4\*.42(ENV4)

Twin2Y5\*.58(ENV5);

!Factor Means Constrained to Zero;

[a1@0 c@0 e1@0 e2@0 ];

!Factor variances Constrained to Unity;

a1@1 c@1 e1@1 e2@1 ;

!Manifest Variable Intercepts Constrained to Equality Across Twin Pairs.;

[twin1y1\*1 twin2y1\*1 ] (y1interc);

[twin1y2\*1 twin2y2\*1 ] (y2interc);

[twin1y3\*1 twin2y3\*1 ] (y3interc);

[twin1y4\*1 twin2y4\*1 ] (y4interc);

[twin1y5\*1 twin2y5\*1 ] (y5interc);

!Error Variances of Manifest Variables Constrained to Equality Across Twin Pairs.

twin1y1\*.34 twin2y1\*.34 (Err1);

twin1y2\*.34 twin2y2\*.34 (Err2);

twin1y3\*.41 twin2y3\*.41 (Err3);

twin1y4\*.30 twin2y4\*.30 (Err4);

twin1y5\*.34 twin2y5\*.34 (Err5);

!Phantom Latent Variable Required for Dizygotic Group (Mean and Variance Fixed to Zero);

a2 by Twin2y1@.3;

a2@0;

[a2@0];

%zygosity#2% !Begin DZ twin model specification;

!Additive Genetic Factor for Twin 1 (Note Twin 2 loadings constrianed to Zero);

a1 by

Twin1Y1\*0.4(Addit1)

Twin1Y2\*0.4(Addit2)

Twin1Y3\*0.4(Addit3)

Twin1Y4\*0.4(Addit4)

Twin1Y5\*0.4(Addit5)

Twin2Y1@0

Twin2Y2@0

Twin2Y3@0

Twin2Y4@0

Twin2Y5@0;

!Common Environmental Factor;

c by

Twin1Y1\*.57(Comm1)

Twin1Y2\*.57 (Comm2)

Twin1Y3\*.5 (Comm3)

Twin1Y4\*.5 (Comm4)

Twin1Y5\*.45(Comm5)

Twin2Y1\*.57(Comm1)

Twin2Y2\*.57 (Comm2)

Twin2Y3\*.5 (Comm3)

Twin2Y4\*.5 (Comm4)

Twin2Y5\*.45(Comm5);

!Unique Environment Factor for Twin 1;

e1 by

Twin1Y1\*.42 (ENV1)

Twin1Y2\*.42 (ENV2)

Twin1Y3\*.42 (ENV3)

Twin1Y4\*.42 (ENV4)

Twin1Y5\*.58 (ENV5);

!Unique Environment Factor for Twin 2;

e2 by

Twin2Y1\*.42 (ENV1)

Twin2Y2\*.42 (ENV2)

Twin2Y3\*.42 (ENV3)

Twin2Y4\*.42 (ENV4)

Twin2Y5\*.58 (ENV5);

!Factor Means set to Zero Factor Variances set to One;

[a1@0 c@0 e1@0 e2@0 ];

a1@1 c@1 e1@1 e2@1 ;

! Manifest Variable Intercepts set to Equality Across Twin Pairs;

[twin1y1\*1 twin2y1\*1 ] (y1interc);

[twin1y2\*1 twin2y2\*1 ] (y2interc);

[twin1y3\*1 twin2y3\*1 ] (y3interc);

[twin1y4\*1 twin2y4\*1 ] (y4interc);

[twin1y5\*1 twin2y5\*1 ] (y5interc);

!Error Variances Set to Equality Across Twin Pairs;

twin1y1\*.34 twin2y1\*.34 (Err1);

twin1y2\*.34 twin2y2\*.34 (Err2);

twin1y3\*.41 twin2y3\*.41 (Err3);

twin1y4\*.30 twin2y4\*.30 (Err4);

twin1y5\*.34 twin2y5\*.34 (Err5);

!Additive Genetic Factor Twin 2;

a2 by

Twin2Y1\*0.4(Addit1)

Twin2Y2\*0.4(Addit2)

Twin2Y3\*0.4(Addit3)

Twin2Y4\*0.4(Addit4)

Twin2Y5\*0.4(Addit5);

a2@1;

[a2@0];

a1 with a2@.5; !Dizygotic Additive Genetic Factor Constrained to .5;

OUTPUT: TECH1 TECH8 TECH9;!Request Model Specification, optimization history, and Monte Carlo Error Messages;

SAVEDATA: RESULTS ARE Twin\_Bayes\_Intercept\_out.txt;!Save Model Results;

!PLOT: TYPE IS PLOT3; !Uncomment if a single data set it analyzed and graphic output is desired.

Appendix B. Mplus Program for Fitting Final Bayesian Random Intercept Model for Simulated Data.

TITLE: Program code example of Bayesian Estimation of Final Model for Simulated Data (AI, C,CI,E,EI).Example considered consists of five variables.

!DATA: file = twin1.dat; TYPE = MONTECARLO; !If analyzing individual data set, uncomment this line and comment out next two lines.

DATA: FILE = twinlist.dat; !file containing names of Monte Carlo Replications;

TYPE = MONTECARLO;!Request Monte Carlo Analysis;

VARIABLE:

NAMES = twin1y1-twin1y5 twin2y1-twin2y5 group; !Variable names. Group indicates zygosity;

USEVARIABLES twin1y1-twin1y5 twin2y1-twin2y5 ;

CLASSES = zygosity (2); !Specify zygosity variable;

KNOWNCLASS = zygosity (group=1 group=2);

ANALYSIS:

MODEL=NOCOVARIANCES; TYPE = MIXTURE;ESTIMATOR=BAYES;

FBITERATION=5000;THIN=50;CHAIN=1;

MODEL:

%OVERALL% !Begin MZ twin program specification;

!Additive Genetic Random Intercept Factor Specified as Single Factor (i.e., Correlation=1 across Twin Pairs);

a1I by

Twin1Y1\*.4 (IAddit1)

Twin1Y2\*.4 (IAddit1)

Twin1Y3\*.4 (IAddit1)

Twin1Y4\*.4 (IAddit1)

Twin1Y5\*.4 (IAddit1)

Twin2Y1\*.4 (IAddit1)

Twin2Y2\*.4 (IAddit1)

Twin2Y3\*.4 (IAddit1)

Twin2Y4\*.4 (IAddit1)

Twin2Y5\*.4 (IAddit1);

!Common Environmental Factor;

c by

Twin1Y1\*.4 (Comm1)

Twin1Y2\*-.4 (Comm2)

Twin1Y3\*.3 (Comm3)

Twin1Y4\*-.3 (Comm4)

Twin1Y5\*.2 (Comm5)

Twin2Y1\*.4 (Comm1)

Twin2Y2\*-.4 (Comm2)

Twin2Y3\*.3 (Comm3)

Twin2Y4\*-.3 (Comm4)

Twin2Y5\*.2 (Comm5);

!Common Environmental Random Intercept Factor;

cI by

Twin1Y1\*.4 (IComm1)

Twin1Y2\*.4 (IComm1)

Twin1Y3\*.4 (IComm1)

Twin1Y4\*.4 (IComm1)

Twin1Y5\*.4 (IComm1)

Twin2Y1\*.4 (IComm1)

Twin2Y2\*.4 (IComm1)

Twin2Y3\*.4 (IComm1)

Twin2Y4\*.4 (IComm1)

Twin2Y5\*.4 (IComm1);

!Unique Environment Factor for Twin 1;

e1 by

Twin1Y1\*-.3 (ENV1)

Twin1Y2\*-.3 (ENV2)

Twin1Y3\*.3 (ENV3)

Twin1Y4\*.3 (ENV4)

Twin1Y5\*.5 (ENV5);

!Unique Environment Random Intercept Factor for Twin 1;

e1I by

Twin1Y1\*.3 (IENV1)

Twin1Y2\*.3 (IENV1)

Twin1Y3\*.3 (IENV1)

Twin1Y4\*.3 (IENV1)

Twin1Y5\*.3 (IENV1);

!Unique Environment Factor for Twin 2;

e2 by

Twin2Y1\*-.3 (ENV1)

Twin2Y2\*-.3 (ENV2)

Twin2Y3\*.3 (ENV3)

Twin2Y4\*.3 (ENV4)

Twin2Y5\*.5 (ENV5);

!Unique Environment Random Intercept Factor for Twin 2;

e2I by

Twin2Y1\*.3 (IENV1)

Twin2Y2\*.3 (IENV1)

Twin2Y3\*.3 (IENV1)

Twin2Y4\*.3 (IENV1)

Twin2Y5\*.3 (IENV1);

!Factor Means Constrained to Zero. Factor Variances Fixed to Unity;

[ a1I@0 c@0 CI@0 e1@0 e1I@0 e2@0 e2I@0];

a1I@1 c@1 CI@1 e1@1 e1I@1 e2@1 e2I@1;

!Manifest Variable Intercepts Constrained to Equality Across Twin Pairs.;

[twin1y1\*1 twin2y1\*1 ] (y1interc);

[twin1y2\*1 twin2y2\*1 ] (y2interc);

[twin1y3\*1 twin2y3\*1 ] (y3interc);

[twin1y4\*1 twin2y4\*1 ] (y4interc);

[twin1y5\*1 twin2y5\*1 ] (y5interc);

!Error Variances of Manifest Variables Constrained to Equality Across Twin Pairs.;

twin1y1\*.34 twin2y1\*.34 (Err1);

twin1y2\*.34 twin2y2\*.34 (Err2);

twin1y3\*.41 twin2y3\*.41 (Err3);

twin1y4\*.30 twin2y4\*.30 (Err4);

twin1y5\*.34 twin2y5\*.34 (Err5);

!Phantom Latent Variable Required for Dizygotic Group (Mean and Variance Fixed to Zero);

a2i by Twin2y1@.3;

a2i@0;

[a2i@0];

%zygosity#2%!Begin DZ twin model specification;

!Additive Genetic Random Intercept Factor for Twin 1 (Note Twin 2 loadings constrianed to Zero);

a1I by

Twin1Y1\*.4 (IAddit1)

Twin1Y2\*.4 (IAddit1)

Twin1Y3\*.4 (IAddit1)

Twin1Y4\*.4 (IAddit1)

Twin1Y5\*.4 (IAddit1)

Twin2Y1@0

Twin2Y2@0

Twin2Y3@0

Twin2Y4@0

Twin2Y5@0;

!Common Environmental Factor;

c by

Twin1Y1\*.4 (Comm1)

Twin1Y2\*-.4 (Comm2)

Twin1Y3\*.3 (Comm3)

Twin1Y4\*-.3 (Comm4)

Twin1Y5\*.2 (Comm5)

Twin2Y1\*.4 (Comm1)

Twin2Y2\*-.4 (Comm2)

Twin2Y3\*.3 (Comm3)

Twin2Y4\*-.3 (Comm4)

Twin2Y5\*.2 (Comm5);

!Common Environmental Random Intercept Factor;

cI by

Twin1Y1\*.4 (IComm1)

Twin1Y2\*.4 (IComm1)

Twin1Y3\*.4 (IComm1)

Twin1Y4\*.4 (IComm1)

Twin1Y5\*.4 (IComm1)

Twin2Y1\*.4 (IComm1)

Twin2Y2\*.4 (IComm1)

Twin2Y3\*.4 (IComm1)

Twin2Y4\*.4 (IComm1)

Twin2Y5\*.4 (IComm1);

!Unique Environment Factor for Twin 1;

e1 by

Twin1Y1\*-.3 (ENV1)

Twin1Y2\*-.3 (ENV2)

Twin1Y3\*.3 (ENV3)

Twin1Y4\*.3 (ENV4)

Twin1Y5\*.5 (ENV5);

!Unique Environment Random Intercept Factor for Twin 1;

e1I by

Twin1Y1\*.3 (IENV1)

Twin1Y2\*.3 (IENV1)

Twin1Y3\*.3 (IENV1)

Twin1Y4\*.3 (IENV1)

Twin1Y5\*.3 (IENV1);

!Unique Environment Factor for Twin 2;

e2 by

Twin2Y1\*-.3 (ENV1)

Twin2Y2\*-.3 (ENV2)

Twin2Y3\*.3 (ENV3)

Twin2Y4\*.3 (ENV4)

Twin2Y5\*.5 (ENV5);

!Unique Environment Random Intercept Factor for Twin 2;

e2I by

Twin2Y1\*.3 (IENV1)

Twin2Y2\*.3 (IENV1)

Twin2Y3\*.3 (IENV1)

Twin2Y4\*.3 (IENV1)

Twin2Y5\*.3 (IENV1);

!Factor Means set to Zero Factor Variances set to One;

[ a1I@0 c@0 CI@0 e1@0 e1I@0 e2@0 e2I@0];

a1I@1 c@1 CI@1 e1@1 e1I@1 e2@1 e2I@1;

! Manifest Variable Intercepts set to Equality Across Twin Pairs;

[twin1y1\*1 twin2y1\*1 ] (y1interc);

[twin1y2\*1 twin2y2\*1 ] (y2interc);

[twin1y3\*1 twin2y3\*1 ] (y3interc);

[twin1y4\*1 twin2y4\*1 ] (y4interc);

[twin1y5\*1 twin2y5\*1 ] (y5interc);

!Error Variances Set to Equality Across Twin Pairs;

twin1y1\*.34 twin2y1\*.34 (Err1);

twin1y2\*.34 twin2y2\*.34 (Err2);

twin1y3\*.41 twin2y3\*.41 (Err3);

twin1y4\*.30 twin2y4\*.30 (Err4);

twin1y5\*.34 twin2y5\*.34 (Err5);

!Additive Genetic Random Intercept Factor Twin 2;

a2i by

Twin2Y1\*.4 (IAddit1)

Twin2Y2\*.4 (IAddit1)

Twin2Y3\*.4 (IAddit1)

Twin2Y4\*.4 (IAddit1)

Twin2Y5\*.4 (IAddit1);

a2I@1;

[a2I@0];

a1I with a2I@.5;

OUTPUT: TECH1 TECH8 TECH9; ;!Request Model Specification, optimization history, and Monte Carlo Error Messages;

savedata: results are Twin\_Bayes\_Intercept\_out\_truemodel.txt; !Save Model Results;

plot: type is plot3; !Uncomment if a single data set it analyzed and graphic output is desired.

Table S1: Bias Estimates For Simulated Data.

|  |  |  |
| --- | --- | --- |
|  | Bayesian Estimation | ML Estimation[[1]](#footnote-1) |
| Parameter | Bias Mean (S.D.) | Bias Mean(S.D.) |
| A loadings | 0.004 (0.022) | N/A |
| AIntercept loadings | -2.43%(0.000) | -0.05% (0.000) |
| C loadings | -1.29% (0.010) | -0.06% (0.001) |
| CIntercept loadings | -2.28% (0.000) | -0.48% (0.000) |
| E loadings | -0.38% (0.004) | -0.10% (0.001) |
| EIntercept loadings | -0.27% (0.000) | -0.20% (0.000) |

Table S2: Summary of Two Factor Factor Loading Estimation Bias[[2]](#footnote-2)

|  |  |  |
| --- | --- | --- |
|  | Bayesian Estimation | ML Estimation |
| Parameter | Bias Mean (S.D.) | Bias Mean(S.D.) |
| A1 loadings | 0.20 (0.008) | N/A |
| A2 loadings | -97.6%(0.010) | -53.2% (0.170) |
| C1 loadings | 26.9% (0.708) | 69.3% (0.791) |
| C2 loadings | -32.0% (0463) | -27.3% (0.403) |
| E1 loadings | -9.5% (0.550) | -12.5% (0.743) |
| E2 loadings | -23.5% (0.545) | -20.1% (0.628) |

Table S3: Competitive ML Models' BIC, χ2, RMSEA, CFI of BMI Data

|  |  |  |  |  |
| --- | --- | --- | --- | --- |
| Model | BIC | χ2(*df*) | RMSEA | CFI |
| AAIntercept,EIntercept | -5165.732 | 1221.610(305) | 0.065 | 0.868 |
| Two factor | -4976.198 | 1041.051(242) | 0.059 | 0.9 |
| RI full model | -5115.218 | 1107.005(278) | 0.06 | 0.892 |
| A,C,CIntercept,E,EIntercept | -5090.255 | 1137.662(279) | 0.063 | 0.884 |
| A,AIntercept,C,E,EIntercept | -5122.506 | 1105.411(279) | 0.06 | 0.893 |
| A,AIntercept,C,CIntercept,E | -5083.257 | 1144.659(279) | 0.063 | 0.882 |
| AIntercept,AIntercept,CIntercept,EIntercept | -5102.345 | 1131.266(280) | 0.062 | 0.886 |
| A,C,CIntercept,E | -5074.192 | 1159.418(280) | 0.064 | 0.878 |
| A,AIntercept,C,E | -5088.795 | 1144.816(280) | 0.063 | 0.882 |
| A, C, E (Genetic Factor Model) | -5079.112 | 1160.193(281) | 0.064 | 0.878 |
| AIntercept,C,CIntercept,E,EIntercept | -5335.937 | 1153.107(292) | 0.062 | 0.883 |
| A,AIntercept, CIntercept,E,EIntercept | -5153.533 | 1148.402(292) | 0.062 | 0.884 |
| A,AIntercept,C,CIntercept, EIntercept | -5121.013 | 1180.923(292) | 0.064 | 0.875 |
| AIntercept, CIntercept,E,EIntercept | -5140.863 | 1240.784(306) | 0.067 | 0.862 |
| AIntercept,C,CIntercept, EIntercept | -5139.217 | 1242.43(306) | 0.067 | 0.862 |
| AInterceptCInterceptEIntercept | -5004.396 | 1456.964(320) | 0.078 | 0.806 |
| AE | -5052.035 | 1266.982 (305) | 0.078 | 0.806 |

1. When full Random Intercept Model is fit, ML estimates do not converse. Results shown for correct mdoel (in which no AS factor is fit to the data. [↑](#footnote-ref-1)
2. A1 and A2 denote freely estimated factors for additive genetic component. C1 and C2 denote similarly designed factors for common environmental effects. E1 and E2 denote freely estimated factors for unique environmental effects. [↑](#footnote-ref-2)